[comment about]
Scripted by Kalizander
Submitted 10/03/2003

It is a system where you can select a certain number of players to provide guidance to new players. 
They can be paged just like gm's can be paged but have no additional special powers. 
When they answer a page they are stripped of everything they own and it is put in their bankbox. 
An event is equiped so they can no longer fight monsters, they are made invul and get a special robe. 
When the page is deleted or they reque, the process is reversed.
They drop all items they acquired during the page, get all their previous items back and are teleported to their original location. 

They're have been a few special precautions so they can't just use it to escape a fight. 

Basically they can just keep on playing as regular players but can offer advice where it is required. 

[comment instructions]
To install, put the script in the script folder and add an i_global_guide_register and keep it safe somewhere. 
All pages, and a list of guides will be kept on there.

Everything else is handled with commands
.guideoptions 

A gm command to hire/fire guides
.guidepage 

Command to page for regular players, command to bring up the pagemenu for other players.
.goffice

Go to the guideoffice.
.guide(something to say)

Guide chat function.

//add the following 3 lines to [plevel 1]
guidepage
goffice
guide

//add the following line to [plevel 4]
guideoptions


[function guideoptions]
finduid(<?var.globalguideregistry?>).dialog d_dialog_guideoptions
return 1

[DIALOG d_dialog_guideoptions]
SetLocation=20,30
 page 0 
 resizepic 0 0 5054 550 180 
 resizepic 10 10 3000 530 160 
textA(55,50,2301,"Hire a guide")
 button 20 50 4005 4007 1 0 1 
textA(55,80,2301,"Fire a guide(Target)")
 button 20 80 4005 4007 1 0 2
textA(55,110,2301,"Fire a guide(List)")
 button 20 110 4005 4007 1 0 3 

[DIALOG d_dialog_guideoptions TEXT]

[DIALOG d_dialog_guideoptions BUTTON]
on=1
Hireguide
return 1
on=2
Fireguide
return 1
on=3
tag.menustartindex=0
f_populate_guildmemberlist(0,"tag.guide")
dialog d_list_guides
return 1

[DIALOG d_list_guides]
setlocation=20,30
 nomove 
 page 0 
 resizepic 0 0 5054 550 440 
 resizepic 10 10 3000 530 420 
 xmfhtmlgump 335 400 100 35 1011012 0 0 
 button 300 400 4005 4007 1 0 1 
 xmfhtmlgump 55 400 245 30 1011120 0 0 
 button 20 400 4005 4007 1 0 0 

 button 20 350 5223 5223 1 0 2
 xmfhtmlgump 45 347 300 30 1011067 0 0 
 button 366 350 5224 5224 1 0 3 
 xmfhtmlgump 288 347 200 30 1011066 0 0 

 page 1 

radio 20 78 5002 5003 0 1
 text 55 75 0 4
radio 20 103 5002 5003 0 2
 text 55 100 0 5
radio 20 128 5002 5003 0 3
 text 55 125 0 6
radio 20 153 5002 5003 0 4
 text 55 150 0 7
radio 20 178 5002 5003 0 5
 text 55 175 0 8 
radio 20 203 5002 5003 0 6
 text 55 200 0 9
radio 20 228 5002 5003 0 7
 text 55 225 0 10 
radio 20 253 5002 5003 0 8
 text 55 250 0 11
radio 20 278 5002 5003 0 9
 text 55 275 0 12
radio 20 303 5002 5003 0 10
 text 55 300 0 13
 text 200 40 0 0  

 text 320 120 0 14
 text 320 150 0 15
 text 320 180 0 16

 button 290 269 4005 4007 1 0 4 
 text 330 270 0 17


[DIALOG d_list_guides TEXT]
GUIDES
Next page
Previous page
To the main menu
<?tag.guildlistmember1?>
<?tag.guildlistmember2?>
<?tag.guildlistmember3?>
<?tag.guildlistmember4?>
<?tag.guildlistmember5?>
<?tag.guildlistmember6?>
<?tag.guildlistmember7?>
<?tag.guildlistmember8?>
<?tag.guildlistmember9?>
<?tag.guildlistmember10?>
Select the Guide you wish to
fire and Push The Fire this 
Guide button
Fire this guide

[DIALOG d_list_guides BUTTON]
on=0 //to main menu
return 1
on=1 //Exit
return 1


on=2 //Previous page
if <tag.menustartindex> > 9
tag.menustartindex=<?tag.menustartindex?>-10
f_populate_guildmemberlist(<?tag.menustartindex?>,"tag.guide")
dialog d_list_guides
return 1
else
dialog d_list_guides
endif
return 1

on=3 //Next page
tag.menustartindex=<?tag.menustartindex?>+10
f_populate_guildmemberlist(<?tag.menustartindex?>,"tag.guide")
dialog d_list_guides
return 1

on=4

if <?ARGCHK(1)?>
if (<?eval <?tag.menustartindex?>+1?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+1?>)
endif
endif
if <?ARGCHK(2)?>
if (<?eval <?tag.menustartindex?>+2?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+2?>)
endif
endif
if <?ARGCHK(3)?>
if (<?eval <?tag.menustartindex?>+3?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+3?>)
endif
endif
if <?ARGCHK(4)?>
if (<?eval <?tag.menustartindex?>+4?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+4?>)
endif
endif
if <?ARGCHK(5)?>
if (<?eval <?tag.menustartindex?>+5?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+5?>)
endif
endif
if <?ARGCHK(6)?>
if (<?eval <?tag.menustartindex?>+6?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+6?>)
endif
endif
if <?ARGCHK(7)?>
if (<?eval <?tag.menustartindex?>+7?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+7?>)
endif
ebdif
if <?ARGCHK(8)?>
if (<?eval <?tag.menustartindex?>+8?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+8?>)
endif
endif
if <?ARGCHK(9)?>
if (<?eval <?tag.menustartindex?>+9?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+9?>)
endif
endif
if <?ARGCHK(10)?>
if (<?eval <?tag.menustartindex?>+10?> <= <?tag.numberofguides?>)
f_remove_guide_by_index(<?eval <?tag.menustartindex?>+10?>)
endif
endif

src.sysmessage "The guide Has been removed from your service"
f_populate_guildmemberlist(<?tag.menustartindex?>,"tag.guide")
dialog d_list_guides
return 1






[function f_add_a_new_guide] //default object is the guidestone, <?args?> is the uid of the new guide.
finduid(<?args?>).tag.isguide=1
tag.numberofguides=<?tag.numberofguides?>+1
tag.guide<?tag.numberofguides?>=<?args?>
return 1

[function f_remove_a_guide_by_uid] //default object is the guidestone, <?args?> is the uid of the new guide.
tag.teller=1
finduid(<?args?>).tag.isguide=""
while (<?tag.teller?> <= <?tag.numberofguides?>)
if (<?args?> == <?tag.guide<?tag.teller?>?>)
if (<?tag.teller?> == <?tag.numberofguides?>)
tag.guide<?tag.teller?>=""
else
tag.guide<?tag.teller?>=<?tag.guide<?tag.numberofguides?>?>
tag.guide<?tag.numberofguides?>=""
endif
tag.numberofguides=<?tag.numberofguides?>-1
endif
tag.teller=<?tag.teller?>+1
endwhile
return 1

[function f_remove_guide_by_index] //default object is the guidestone, <?args?> is the guide index
finduid(<?tag.guide<?args?>?>).tag.isguide=""
if <?args?>==<?tag.numberofguides?>
tag.guide<?args?>=""
else
tag.guide<?args?>=<?tag.guide<?tag.numberofguides?>?>
tag.guide<?tag.numberofguides?>=""
tag
endif
tag.numberofguides=<?tag.numberofguides?>-1
return 1

[function Hireguide]
src.newitem i_add_guide_targ
src.act.equip
src.act.targetg "Who do you wish to make guide?"
return 1

[ITEMDEF i_add_guide_targ]
NAME="Add Guide memory Memory"
ID=i_handr_1
TYPE=T_EQ_SCRIPT
LAYER=30

ON=@CREATE
	attr_decay=1
	TIMER=60

ON=@EQUIP
	TIMER=60
	TARGET
	return 1

on=@timer
     remove
     return 1

ON=@TARGON_CHAR
 if <?src.targ.tag.isguide?>
	src.sysmessage "This person is allready a guide, remove tag.isguide and readd him if he's no longer listed"
	remove
	return 1
 else
	finduid(<?var.globalguideregistry?>).f_add_a_new_guide(<?src.targ.uid?>)
	src.sysmessage "This Person has been made guide."
	src.targ.sysmessage "You have been promoted to guide."
	remove
	return 1
 endif
	remove
	return 1

on=@targon_item
	src.sysmessage="Invalid target."
	remove
	return 1

[function Fireguide]
src.newitem i_Fire_guide_targ
src.act.equip
src.act.targetg "Target the guide you wish to fire."
return 1

[ITEMDEF i_Fire_guide_targ]
NAME="Fire Guide memory"
ID=i_handr_1
TYPE=T_EQ_SCRIPT
LAYER=30

ON=@CREATE
	attr_decay=1
	TIMER=60

ON=@EQUIP
	TIMER=60
	TARGET
	return 1

on=@timer
     remove
     return 1

ON=@TARGON_CHAR
 if <?src.targ.tag.isguide?>
	src.sysmessage "You have been stripped from guidestatus."
	finduid(<?var.globalguideregistry?>).f_remove_a_guide_by_uid(<?src.targ.uid?>)
	remove
	return 1
 else
	src.sysmessage "This person is not a guide."
	remove
	return 1
 endif
remove
return 1

on=@targon_item
	src.sysmessage="Invalid target."
	remove
	return 1

[itemdef i_global_guide_Register]
ID=0EDD
type=t_eq_script
name=Global Guide registry

on=@create
color=0800
tag.numberofpages=0
tag.numberofguides=0
var.globalguideregistry=<uid>

on=@UserDclick
var.globalguideregistry=<uid>
return 1

[FUNCTION guidepage]
if <?src.tag.isguide?>
finduid(<?var.globalguideregistry?>).dialog d_guide_page_system
else
finduid(<?var.globalguideregistry?>).dialog d_give_reason_of_guidepage
endif
return 1

[DIALOG d_give_reason_of_guidepage]
setlocation=20,30
 nomove 
 page 0 
 resizepic 0 0 5054 550 160 
 resizepic 10 10 3000 530 140 
 text 40 40 0 0
 TEXTA(55,120,2301,"Send this page")
 TEXTA(335,120,2301,"Cancel") 
 button 20 120 4005 4007 1 0 1
 button 300 120 4005 4007 1 0 2
 resizepic 20 70 5054 480 30
 textentry 26 75 460 30 15 1 10


[DIALOG d_give_reason_of_guidepage TEXT]
GIVE THE REASON OF YOUR GUIDEPAGE:


[DIALOG d_give_reason_of_guidepage BUTTON]
on=0
return 1
on=1 //send page
src.sysmessage "Your page has been received."
f_send_guide_page("<ARGTXT(1)>")
return 1
on=2 //cancel
return 1

[function f_send_guide_page] //args=reason src=src.player
tag.numberofpages=<?tag.numberofpages?>+1
tag.page<?tag.numberofpages?>_reason="<?args?>"
tag.page<?tag.numberofpages?>_player=<?src.uid?>
tag.page<?tag.numberofpages?>_location=<?src.p?>
tag.page<?tag.numberofpages?>_status=0
f_send_guide_sysmessage("<?args?>")
return 1

[function f_send_guide_sysmessage]
tag.teller=1
while (<?tag.teller?> <= <?tag.numberofguides?>)
finduid(<?tag.guide<?tag.teller?>?>).SysMessageT(0,053,100,3,"A new guide page from <?src.name?>: <?args?>")
tag.teller=<?tag.teller?>+1
endwhile
tag.teller=""

[function f_remove_guidepage_by_index] //args=index
if <?args?>==<?tag.numberofpages?>
tag.page<?args?>_reason=""
tag.page<?args?>_player=""
tag.page<?args?>_location=""
tag.page<?args?>_status=""
else
tag.page<?args?>_reason=<?tag.page<?tag.numberofpages?>_reason?>
tag.page<?args?>_player=<?tag.page<?tag.numberofpages?>_player?>
tag.page<?args?>_location=<?tag.page<?tag.numberofpages?>_location?>
tag.page<?args?>_status=<?tag.page<?tag.numberofpages?>_status?>
tag.page<?tag.numberofpages?>_reason=""
tag.page<?tag.numberofpages?>_player=""
tag.page<?tag.numberofpages?>_location=""
tag.page<?tag.numberofpages?>_status=""
endif
tag.numberofpages=<?tag.numberofpages?>-1
return 1

[DIALOG d_guide_page_system]
SetLocation=5,80				// ok*
page 0						// page 1*
resizepic(0,0,5054,800,517)			// window*
gumppictiled  10  10  780   22 2624		// title bar*
gumppictiled  10  37  160  450 2624		// navigation panel*
gumppictiled 175  37  615  450 2624		// main panel
gumppictiled  10 490  780  25  2624		// status panel*
checkertrans  10  10  780  507			// make window transparent
text          30  12 2301    0			// Main Title bar text
text         345  12 2301    1			// title bar: console area text
button       760  10 4017 4019     1 0  0	// exit button*
//button       200  495 04b9 04ba    1 0  1	// sort button*
//button       400  495 04b9 04ba    1 0  2	// sort button*
//button       600  495 04b9 04ba    1 0  3	// sort button*

	textA(25,35,2301,"goto")
	textA(60,35,2301,"del")
	textA(93,35,2301,"loc")				//MESSAGE
	textA(126,35,2301,"reque")			//ADMIN

	textA(190,35,2301,"Location")			
	textA(280,35,2301,"Player name")			
	textA(405,35,2301,"Status")				
	textA(530,35,2301,"Reason")			


tag.teller=1
say <?tag.numberofpages?>
while (<?tag.teller?> <= <?tag.numberofpages?>)
		// Name, Val

		argo.button(20,<?eval <?eval <?tag.teller?>*20?>+50?>,4005,4007,1,0,<?eval <?eval <?tag.teller?>*4?>+5?>) // another action
		argo.button(20+35,<?eval <?eval <?tag.teller?>*20?>+50?>,4005,4007,1,0,<?eval <?eval <?tag.teller?>*4?>+6?>) // another action
		argo.button(20+70,<?eval <?eval <?tag.teller?>*20?>+50?>,4005,4007,1,0,<?eval <?eval <?tag.teller?>*4?>+7?>) // another action
		argo.button(20+105,<?eval <?eval <?tag.teller?>*20?>+50?>,4005,4007,1,0,<?eval <?eval <?tag.teller?>*4?>+8?>) // another action

		argo.textA(190,<?eval <?eval <?tag.teller?>*20?>+50?>,99,"<?tag.page<?tag.teller?>_location?>")
		argo.textA(280,<?eval <?eval <?tag.teller?>*20?>+50?>,99,"<?finduid(<?tag.page<?tag.teller?>_player?>).name?>")
	if (<?tag.page<?tag.teller?>_status?>)
		argo.textA(405,<?eval <?eval <?tag.teller?>*20?>+50?>,99,"Being handled")
	else
		argo.textA(405,<?eval <?eval <?tag.teller?>*20?>+50?>,99,"Unhandled")
	endif
		argo.textA(530,<?eval <?eval <?tag.teller?>*20?>+50?>,99,"<?tag.page<?tag.teller?>_reason?>") // 440 last line to be made before next page

tag.teller=<?tag.teller?>+1
endwhile





[DIALOG d_guide_page_system TEXT]
<?serv.name?> GUIDEPAGE CONSOLE -
Client's Help Que Console

[DIALOG d_guide_page_system BUTTON]
ON=0
	return
ON=@AnyButton
		if (((argn-5)%4)==0)
			if !<?src.isevent(e_guide)?> 
				if (<?src.hits?> == <?src.maxhits?>)
					if !<?tag.page<?eval <?eval <?argn?>-5?>/4?>_status?>
						src.tag.original_location=<?src.p?>
						f_prep_guide_for_page
						tag.page<?eval <?eval <?argn?>-5?>/4?>_status=<?src.uid?>
						src.gouid <?tag.page<?eval <?eval <?argn?>-5?>/4?>_player?>
						return 1
					else
						src.sysmessage "Someone is allready handling this page."
					endif
				else
					src.sysmessage "You must have full hitpoints to use guidepage."
				endif
				
			else
				src.sysmessage "You are still on a page, delete or reque it first."
				return 1
			endif
		endif
		if (((argn-5)%4)==1)

		if (<?tag.page<?eval <?eval <?argn?>-5?>/4?>_status?>)
			if (<?tag.page<?eval <?eval <?argn?>-5?>/4?>_status?> == <?src.uid?>)
				f_remove_guidepage_by_index(<?eval <?eval <?argn?>-5?>/4?>)
			else
				src.sysmessage "You can not delete a page that someone else is currently handling."
			endif
		else
				f_remove_guidepage_by_index(<?eval <?eval <?argn?>-5?>/4?>)
		endif
			if <?src.isevent(e_guide)?>
				f_unprep_guide_for_page
				src.go <?src.tag.original_location?>
				src.tag.original_location=""
				return 1
			endif
		endif
		if (((argn-5)%4)==2)
			if !<?src.isevent(e_guide)?>	
				if (<?src.hits?> == <?src.maxhits?>)
					if !<?tag.page<?eval <?eval <?argn?>-5?>/4?>_status?>
						src.tag.original_location=<?src.p?>
						f_prep_guide_for_page
						tag.page<?eval <?eval <?argn?>-5?>/4?>_status=<?src.uid?>
						src.go <?tag.page<?eval <?eval <?argn?>-5?>/4?>_location?>
						return 1
					else
						src.sysmessage "Someone is allready handling this page."
					endif
				else
					src.sysmessage "You must have full hitpoints to use guidepage."
				endif
			else
				src.sysmessage "You are still on a page, delete or reque it first."
				return 1
			endif
		endif
		if (((argn-5)%4)==3)
			if (<?src.isevent(e_guide)?>) && (<?tag.page<?eval <?eval <?argn?>-5?>/4?>_status?> == <?src.uid?>)
				f_unprep_guide_for_page
				src.go <?src.tag.original_location?>
				tag.page<?eval <?eval <?argn?>-5?>/4?>_status=0
				src.tag.original_location=""
				return 1
			else
				src.sysmessage "You can not reque a page you are not handling yourself."
			endif
		endif
	
[function goffice]
if (<?src.tag.isguide?>)
	if (<?src.hits?> == <?src.maxhits?>)
		if 0<?src.tag.isinoffice?>
			src.tag.isinoffice=""
			src.go <?src.tag.original_location?>
			src.tag.original_location=""
			return 1
		else
			src.tag.original_location=<?src.p?>
			src.tag.isinoffice=1
			src.go 5643,1034,20
			return 1
		endif
	else
		src.sysmessage "You must have full hitpoints to use guidepage."
	endif
else
	src.sysmessage "You must be a guide to use this."
endif

[function guide]
if (<?src.tag.isguide?>)
        finduid(<?var.globalguideregistry?>).f_send_guide_messages("<?args?>")
else
	src.sysmessage "You must be a guide to use this."
endif


[function f_send_guide_messages]
tag.teller=1
while (<?tag.teller?> <= <?tag.numberofguides?>)
	finduid(<?tag.guide<?tag.teller?>?>).SysMessageT(0,030,100,3,"<?src.name?>[guide] : <?args?>")
tag.teller=<?tag.teller?>+1
endwhile


[function f_prep_guide_for_page]
src.events +e_guide
src.tag.guidebackpackuid=<?src.findlayer(21).uid?>
src.findlayer(21).cont=<?src.findlayer(layer_bankbox)?>
finduid(<?src.tag.guidebackpackuid?>).color=0
src.newitem i_backpack
src.tag.guideequipmentuid=<?src.act.uid?>
src.act.cont=<?src.findlayer(layer_bankbox)?>
src.findlayer(1).cont=<?src.act.uid?>
src.findlayer(2).cont=<?src.act.uid?>
src.findlayer(3).cont=<?src.act.uid?>
src.findlayer(4).cont=<?src.act.uid?>
src.findlayer(5).cont=<?src.act.uid?>
src.findlayer(6).cont=<?src.act.uid?>
src.findlayer(7).cont=<?src.act.uid?>
src.findlayer(8).cont=<?src.act.uid?>
src.findlayer(10).cont=<?src.act.uid?>
src.findlayer(12).cont=<?src.act.uid?>
src.findlayer(13).cont=<?src.act.uid?>
src.findlayer(14).cont=<?src.act.uid?>
src.findlayer(17).cont=<?src.act.uid?>
src.findlayer(18).cont=<?src.act.uid?>
src.findlayer(19).cont=<?src.act.uid?>
src.findlayer(20).cont=<?src.act.uid?>
src.findlayer(22).cont=<?src.act.uid?>
src.findlayer(23).cont=<?src.act.uid?>
src.findlayer(24).cont=<?src.act.uid?>
src.findlayer(31).cont=<?src.act.uid?>
SRC.FINDLAYER(25).cont=<?src.act.uid?>
src.act.drop
src.act.open
src.act.cont=<?src.findlayer(layer_bankbox)?>
src.act.color=0
src.newitem i_robe_gm
src.act.color 05
src.act.name "Guide robe"
src.act.equip
src.act.attr=08010
//src.tag.guidebankuid=<?src.findlayer(layer_bankbox)?>
//src.findlayer(layer_bankbox).type=t_normal
src.newitem i_backpack
src.act.equip
src.invul 1
src.update

[function f_unprep_guide_for_page]
//finduid(<?src.tag.guidebankuid?>).layer=29
//finduid(<?src.tag.guidebankuid?>).type=t_eq_bank_box
src.findlayer(21).drop
src.findlayer(1).drop
src.findlayer(2).drop
src.findlayer(3).drop
src.findlayer(4).drop
src.findlayer(5).drop
src.findlayer(6).drop
src.findlayer(7).drop
src.findlayer(8).drop
src.findlayer(10).drop
src.findlayer(12).drop
src.findlayer(13).drop
src.findlayer(14).drop
src.findlayer(17).drop
src.findlayer(18).drop
src.findlayer(19).drop
src.findlayer(20).drop
src.findlayer(22).remove
src.findlayer(23).drop
src.findlayer(24).drop
src.findlayer(31).drop
src.findlayer(25).link.remove
src.findlayer(25).remove
finduid(<?src.tag.guidebackpackuid?>).layer=21
finduid(<?src.tag.guidebackpackuid?>).equip
finduid(<?src.tag.guideequipmentuid?>).f_reequip_all_guide_items
finduid(<?src.tag.guideequipmentuid?>).remove
src.events -e_guide
src.invul 0
src.tag.guidebankuid=""
src.tag.guidebackpackuid=""
src.tag.guideequipmentuid=""
return 1


[function f_reequip_all_guide_items]
while <?rescount?>
findcont(0).cont=<?src.uid?>
endwhile
return 1

[function f_populate_guildmemberlist] //argv(0)=startindex argv(1)="tag.member" to load members, "tag.trial" to load trial members "link.tag.guild" to load all guilds
f_clean_guildmemberlist
if (<?<?argv(1)?><?eval <?argv(0)?>+1?>?> )
	tag.guildlistmember1="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+1?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+2?>?> )
	tag.guildlistmember2="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+2?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+3?>?> )
	tag.guildlistmember3="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+3?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+4?>?> )
	tag.guildlistmember4="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+4?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+5?>?> )
	tag.guildlistmember5="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+5?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+6?>?> )
	tag.guildlistmember6="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+6?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+7?>?> )
	tag.guildlistmember7="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+7?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+8?>?> )
	tag.guildlistmember8="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+8?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+9?>?> )
	tag.guildlistmember9="<?finduid(<?<?argv(1)?>r<?eval <?argv(0)?>+9?>?> ).name?>"
endif
if (<?<?argv(1)?><?eval <?argv(0)?>+10?>?> )
	tag.guildlistmember10="<?finduid(<?<?argv(1)?><?eval <?argv(0)?>+10?>?> ).name?>"
endif

[function f_clean_guildmemberlist]
tag.guildlistmember1=""
tag.guildlistmember2=""
tag.guildlistmember3=""
tag.guildlistmember4=""
tag.guildlistmember5=""
tag.guildlistmember6=""
tag.guildlistmember7=""
tag.guildlistmember8=""
tag.guildlistmember9=""
tag.guildlistmember10=""

[typedef t_unaccesible_container]
on=@userdclick
return 1

[events e_guide]
on=@hittry
action=-1
return 1

on=@userclick
messagetable(0,035,3,"[GUIDE]")
messagetable(0,05,3,"<?name?>")
Objprop 0,<name>
Objprop 0,"GUIDE"
return 1



[eof]